// ad_delete

footer_del(TX* text, txstr begin_of_footer)
{
	txstr	next_mail = ":_      ";
	
	jumpfiletop();
	while(searchex(begin_of_footer,SEARCH_FORWARD)){
		selectex(CLIP_PARA);
		if(!searchex(next_mail,SEARCH_FORWARD))
			jumpfileend();
		selectdelete();
	}
}

computer_eigo(TX* text)
{
	txstr	end_of_mail = "■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■";
	
	footer_del(text, end_of_mail);
}

cnet_ad_del(TX* text)
{
	txstr	start_of_ad = "*************************************** advertisement *********";
	txstr	end_of_ad = "************************************************************** ";
	
	jumpfiletop();
	while(searchex(start_of_ad,SEARCH_FORWARD)){
		selectex(CLIP_PARA);
		searchex(end_of_ad,SEARCH_FORWARD);
		nextpara();
		selectdelete();
	}
}

cnet(TX* text)
{
	txstr	start_of_footer = "***************************************also from CNET*********";
	
	cnet_ad_del(text);
	footer_del(text, start_of_footer);
}

ascii24_ad_del(TX* text, txstr start_of_ad)
{
	txstr	middle_of_pr = "─────────────────────────────────────";
	txstr	end_of_pr = "────────────────────────────────── PR ─";
	txstr	big_news = "■ビッグニュース";
	txstr	next_mail = ":_      ";
	txstr	current_line;
	
	jumpfiletop();
	while(searchex(start_of_ad,SEARCH_FORWARD)){
		selectex(CLIP_PARA);
		searchex(middle_of_pr,SEARCH_FORWARD);
		nextpara();
		nextpara();
		getpara(current_line);
		if(!(big_news == current_line)){
			searchex(end_of_pr,SEARCH_FORWARD);
			nextpara();
		}
		selectdelete();
	}
}

ascii24(TX* text){
	txstr	start_of_pr = "─ PR ──────────────────────────────────";
	txstr	start_of_pickup = "─ PickUP ────────────────────────────────";
	txstr	start_of_footer = "■ニュースURL一覧";
	
	ascii24_ad_del(text, start_of_pr);
	ascii24_ad_del(text, start_of_pickup);
	footer_del(text, start_of_footer);
}

hyphen_del(TX* text)
{
	txstr	separator = "^-----------+";
	txstr	after_separate = "----";
	
	jumpfiletop();
	txReplaceEx(text,separator,after_separate,SEARCH_REWZ);
}

main
{
	txSetUndisp(text);	// 動作高速化のため、textの表示をOFFに
	
	computer_eigo(text);
	cnet(text);
	ascii24(text);
	hyphen_del(text);
	txSetDisp(text);	// textの表示を再開
}